AS3 - Youtube flash API‧flash載入youtube影片、自訂播放暫停按鈕

youtube flash api 官方發布已經有段時間了，但資質不夠一直沒看懂，最近在網路上有找到比較能理解的範例之後，終於有小小的成果了...只不過面版並沒有認真的設計，參考用的加減看看囉!



as3語法如下：

import com.greensock.*;

//指定YouTube Video ID
var myVideoID:String = "JwWML6fDnXw";

//自動播放：true, 不自動播放：false
var autoPlayVideo:Boolean = false;

// 用控制面版：true, 不用控制面版：false
var useControlPanelState:Boolean = false;

//重覆播放：true, 不重覆播放：false
var loopVideoState:Boolean = true;

//聲音大小，最大100，最小：0 (無聲)
var myVolume:Number = 50;

//有聲：false, 無聲：true
var muteVideoState:Boolean = false;




//Below Functions Are Edited By Perr Tang
var autoPlayState:String;
if (autoPlayVideo == true)
{
 autoPlayState = "&autoplay=1";
}
else
{
 autoPlayState = "";
}
var myVideoURL:String;
if (useControlPanelState == true)
{
 myVideoURL = "http://www.youtube.com/v/" + myVideoID + "?version=3" + autoPlayState;
}
else if (useControlPanelState == false)
{
 myVideoURL = "http://www.youtube.com/apiplayer?version=3&video_id=" + myVideoID + autoPlayState;
}
// The player SWF file on www.youtube.com needs to communicate with your host
// SWF file. Your code must call Security.allowDomain() to allow this
// communication.(設定允許跨網域連到youtube.com)
Security.allowDomain("www.youtube.com");

// This will hold the API player instance once it is initialized.;
var player:Object;

var loader:Loader = new Loader();
loader.contentLoaderInfo.addEventListener(Event.INIT, onLoaderInit);


//loader.load(new URLRequest("http://www.youtube.com/apiplayer?version=3&video_id=YHLWdb55iic&autoplay=1"));
loader.load(new URLRequest(myVideoURL));

function onLoaderInit(event:Event):void
{
 addChild(loader);
 loader.content.addEventListener("onReady", onPlayerReady);
 loader.content.addEventListener("onError", onPlayerError);
 loader.content.addEventListener("onStateChange", onPlayerStateChange);
 loader.content.addEventListener("onPlaybackQualityChange",
 onVideoPlaybackQualityChange);
}

function onPlayerReady(event:Event):void
{
 // Event.data contains the event parameter, which is the Player API ID
 trace("player ready:", Object(event).data);

 // Once this event has been dispatched by the player, we can use
 // cueVideoById, loadVideoById, cueVideoByUrl and loadVideoByUrl
 // to load a particular YouTube video.
 player = loader.content;
 // 指定影片大小Set appropriate player dimensions for your application
 player.setSize(580, 435);
 
 // 指定影片位置;
 player.x = 8;
 player.y = 8;
 player.alpha=0; 
 TweenLite.to(player, 0.5, {alpha:1});



 player.setVolume(myVolume);
 if (muteVideoState == true)
 {
  player.mute();
 }

}

function onPlayerError(event:Event):void
{
 // Event.data contains the event parameter, which is the error code
 trace("player error:", Object(event).data);
}

function onPlayerStateChange(event:Event):void
{
 // Event.data contains the event parameter, which is the new player state
 trace("player state:", Object(event).data);
 if (Object(event).data == "0")
 {
  if (loopVideoState == true)
  {
   player.playVideo();
  }
  else
  {
   player.stopVideo();
  }
 }
}

function onVideoPlaybackQualityChange(event:Event):void
{
 // Event.data contains the event parameter, which is the new video quality
 trace("video quality:", Object(event).data);
}

//自訂播放按鈕

play_btn.addEventListener(MouseEvent.CLICK, playVid);
function playVid(e:MouseEvent):void
{
 player.playVideo();
}
play_btn.buttonMode = true;


//自訂暫停按鈕
pause_btn.addEventListener(MouseEvent.CLICK, pauseVid);
function pauseVid(e:MouseEvent):void
{
 player.pauseVideo();
}

pause_btn.buttonMode = true;



//自訂停止按鈕
stop_btn.addEventListener(MouseEvent.CLICK, stopVid);
function stopVid(e:MouseEvent):void
{
 player.stopVideo();
}
stop_btn.buttonMode = true;


//自訂靜音按鈕
mute_btn.addEventListener(MouseEvent.CLICK, muteVid);
function muteVid(e:MouseEvent):void
{
 player.mute();
}
mute_btn.buttonMode = true;


//自訂恢復音量按鈕

unmute_btn.addEventListener(MouseEvent.CLICK, unmuteVid);
function unmuteVid(e:MouseEvent):void
{
 player.unMute();
}
unmute_btn.buttonMode = true;

swf view：http://www.swfcabin.com/open/1312544932
參考範例：
http://www.republicofcode.com/tutorials/flash/as3youtube/
http://benlibra.blogspot.com/2011/03/as3-flashyoutube.html

綜合了二位所提供的語法，我也分享了一下，但目前完整度大概只有70%，希望最後可以研究出進度bar來!


2013.08.13，補上fla原始檔，有需要的朋友請拿去研究~ 下載請點我>>
(按鈕做得很醜，請不要真的拿去專案上使用...)

facebook討論